linphone-sdk-android版本號生成解析

 ./cmake/Android/gradle/upload.gradle.cmake
 ./build/upload.gradle

 include(bctoolbox/cmake/BcToolboxCMakeUtils.cmake)
 bc_compute_full_version(LINPHONESDK_VERSION)

 function(bc_compute_full_version OUTPUT_VERSION)
     # 查詢 Git 程式
     find_program(GIT_EXECUTABLE git NAMES Git CMAKE_FIND_ROOT_PATH_BOTH)
     # 如果找到 Git 程式
     if(GIT_EXECUTABLE)
         # 執行 git describe 命令
         execute_process(
             COMMAND "${GIT_EXECUTABLE}" "describe"
             OUTPUT_VARIABLE GIT_DESCRIBE_VERSION
             OUTPUT_STRIP_TRAILING_WHITESPACE
             ERROR_QUIET
             WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
         )
         # parse git describe version
         # 解析 git describe 的返回值作為版本號, 通過正規表示式的分組匹配進行解析：4.5.26-alpha-9-gb342a93
         # 如果沒有解析到, 輸出錯誤資訊
         if (NOT (GIT_DESCRIBE_VERSION MATCHES "^([0-9]+)[.]([0-9]+)[.]([0-9]+)(-alpha|-beta)?(-[0-9]+)?(-g[0-9a-f]+)?$"))
             message(FATAL_ERROR "invalid git describe version: '${GIT_DESCRIBE_VERSION}'")
         endif()
         # 設定分組1為主要版本: ([0-9]+) -> 4
         set(version_major ${CMAKE_MATCH_1})
         # 設定分組2為次要版本: ([0-9]+) -> 5
         set(version_minor ${CMAKE_MATCH_2})
         # 設定分組3為修補程式版本: ([0-9]+) -> 26
         set(version_patch ${CMAKE_MATCH_3})
         # 如果解析到分組4: (-alpha|-beta)? -> -alpha, 則去掉前面的‘-', 得到後面的‘alpha|beta', 賦值給 version_prerelease
         if (CMAKE_MATCH_4)
             string(SUBSTRING "${CMAKE_MATCH_4}" 1 -1 version_prerelease)
         endif()
         # 如果解析到分組5：(-[0-9]+)? -> -9, 則去掉前面的‘-', 得到後面的‘9', 賦值給 version_commit
         if (CMAKE_MATCH_5)
             string(SUBSTRING "${CMAKE_MATCH_5}" 1 -1 version_commit)
         endif()
         # 如果解析到分組6: (-g[0-9a-f]+)? -> -gb342a93, 則去掉前面的‘-g', 得到後面的‘b342a93', 賦值給 version_hash
         if (CMAKE_MATCH_6)
             string(SUBSTRING "${CMAKE_MATCH_6}" 2 -1 version_hash)
         endif()
         # interpret untagged hotfixes as pre-releases of the next "patch" release
         # 如果沒有 version_prerelease, 但是有 version_commit, 認為是此修補程式程式是下一個修補程式版本的預發版本, 即將修補程式版本號+1
         # 並設定 version_prerelease 為 "pre"
         if (NOT version_prerelease AND version_commit)
             math(EXPR version_patch "${version_patch} + 1")
             set(version_prerelease "pre")
         endif()
         # format full version
         # 拼接主、次、修補程式版本號
         set(full_version "${version_major}.${version_minor}.${version_patch}")
         # 如果有 version_prerelease
         if (version_prerelease)
             # 版本號追加 "-pre"
             string(APPEND full_version "-${version_prerelease}")
             # 如果有 version_commit
             if (version_commit)
                 # 版本號追加 ".9+b342a93"
                 string(APPEND full_version ".${version_commit}+${version_hash}")
             endif()
         endif()
         # 省略其他檢查邏輯
         # 設定版本號為CMake快取引數, 完整版本號: 4.5.27-pre.9+b342a93
         set(${OUTPUT_VERSION} "${full_version}" CACHE STRING "" FORCE)
     endif()
 endfunction()